転勤

4月末に転勤になりました．

今までは地下鉄車両の整備をやってましたが，新しい職場では事務をしてます．
整備員のときに「あれが欲しいこれが欲しい」と要求することがあったのですが，今度はその要求を聞く側です．
まあそれはともかく．
以下，愚痴．

GW

最近，日記らしいことを全然書いていませんでした．

ヘッドフォンのコードに足を引っかけて落として壊してしまったので，
ついにホットボンドを買ってきました．
強度を持たせようと思って盛りすぎたので少しいびつな形になったけど，使用感はまずまず．
これならまだしばらくは使えます．
前からホットボンドが欲しかったんだけど，いざ買うとなると今は特に困ってないからなあ，と思って買いませんでした．
これで色々壊れても直せますね．

母の日だったので，カーネーションをプレゼントしました．喜んでもらえたのかな？
父が仕事で使う長靴が欲しいと言うのでそれも購入．長靴くらいすぐ買えるがな！

最近，家の中で不便なところを探して直していってます．
安価で簡単に改善できるところがたくさんあるので，
ほったらかしにせず注意して見直してます．

さあー明日からまた頑張って恐ろしい職場に行かなきゃ！！＞＜；

スレッドセーフな銀行クラス(2)

すべてのメソッドの内容を synchronized ブロックに含めるのならクラスを synchronized クラスにしてもよい．
synchronized クラスのメンバはそのインスタンスを shared 型で生成しなければ呼び出せないので，この場合には new Bank ではなく new shared(Bank) とする．

import std.stdio;
import core.thread;

synchronized class Bank
{
	private int money_;
	
	void payin(int m)
	{
		money_ += m;
	}
	void payout(int m)
	{
		// お金があるときだけ出金する
		if (money_ - m > 0)
		{
			money_ -= m;
		}
		if (money_ < 0)
		{
			// ここには来ない
			throw new Exception("pay out exception.");
		}
	}
	int money() @property
	{
		return money_;
	}
}

void main()
{
	auto bank = new shared(Bank);
	auto tg = new ThreadGroup;
	bool isRunning = true;
	
	// 100ずつ出金する人
	tg.create = {
		while (isRunning)
		{
			try
			{
				bank.payout(100);
			}
			catch (Exception e)
			{
				isRunning = false; // 両方のスレッドを終了する
				throw e;
			}
		}
	};
	
	// 100ずつ入金する人
	tg.create = {
		while (isRunning)
		{
			bank.payin(100);
		}
	};
	
	// スレッドを回す
	tg.joinAll();
}

スレッドセーフな銀行クラス

適切に synchronized ブロックを使えば利用者側で気をつける必要がなくなる．
クラスメンバの中での synchronized は synchronized (this) と同じ．

import std.stdio;
import core.thread;

class Bank
{
	private int money_;
	
	void payin(int m)
	{
		synchronized
		{
			money_ += m;
		}
	}
	void payout(int m)
	{
		synchronized
		{
			// お金があるときだけ出金する
			if (money_ - m > 0)
			{
				money_ -= m;
			}
		}
		if (money_ < 0)
		{
			// ここには来ない
			throw new Exception("pay out exception.");
		}
	}
	int money() @property
	{
		synchronized
		{
			return money_;
		}
	}
}

void main()
{
	auto bank = new Bank;
	auto tg = new ThreadGroup;
	bool isRunning = true;
	
	// 100ずつ出金する人
	tg.create = {
		while (isRunning)
		{
			try
			{
				bank.payout(100);
			}
			catch (Exception e)
			{
				isRunning = false; // 両方のスレッドを終了する
				throw e;
			}
		}
	};
	
	// 100ずつ入金する人
	tg.create = {
		while (isRunning)
		{
			bank.payin(100);
		}
	};
	
	// スレッドを回す
	tg.joinAll();
}

銀行クラスをスレッドセーフに扱う

どこでどのような競合を起こしうるのか想像するのが難しい．
このようにスレッドセーフに使えるクラスを「スレッドコンパチブルである」という．

import std.stdio;
import core.thread;
import core.sync.mutex;

class Bank
{
	private int money_;
	
	void payin(int m)
	{
		money_ += m;
	}
	void payout(int m)
	{
		money_ -= m;
		if (money_ < 0)
		{
			// ここには来ない
			throw new Exception("pay out exception.");
		}
	}
	int money() @property
	{
		return money_;
	}
}

void main()
{
	auto bank = new Bank;
	auto tg = new ThreadGroup;
	bool isRunning = true;
	auto mutex = new Mutex;
	
	// 100ずつ出金する人
	tg.create = {
		while (isRunning)
		{
			try
			{
				synchronized (mutex)
				{
					if (bank.money >= 100) // 残金を確認して
					{
						foreach (_; 0..10000){} // 異常が起こりやすいように待つ
						// お金があるときだけ出金するはず？
						bank.payout(100);
					}
				}
			}
			catch (Exception e)
			{
				isRunning = false; // 両方のスレッドを終了する
				throw e;
			}
		}
	};
	
	// 100ずつ入金する人
	tg.create = {
		while (isRunning)
		{
			synchronized (mutex)
			{
				bank.payin(100);
			}
		}
	};
	
	// スレッドを回す
	tg.joinAll();
}

スレッドセーフでない銀行クラス

import std.stdio;
import core.thread;

class Bank
{
	private int money_;
	
	void payin(int m)
	{
		money_ += m;
	}
	void payout(int m)
	{
		money_ -= m;
		if (money_ < 0)
		{
			// クラスの利用者が注意していればここには到達しないはず？
			throw new Exception("pay out exception.");
		}
	}
	int money() @property
	{
		return money_;
	}
}

void main()
{
	auto bank = new Bank;
	auto tg = new ThreadGroup;
	bool isRunning = true;
	
	// 100ずつ出金する人
	tg.create = {
		while (isRunning)
		{
			try
			{
				if (bank.money >= 100) // 残金を確認して
				{
					foreach (_; 0..10000){} // 異常が起こりやすいように待つ
					// お金があるときだけ出金するはず？
					bank.payout(100);
				}
			}
			catch (Exception e)
			{
				isRunning = false; // 両方のスレッドを終了する
				throw e;
			}
		}
	};
	
	// 100ずつ入金する人
	tg.create = {
		while (isRunning)
		{
			bank.payin(100);
		}
	};
	
	// スレッドを回す
	tg.joinAll();
}

D言語で「Java言語で学ぶデザインパターン入門【マルチスレッド編】」を学ぶ

本を読みながらコードを書いていきたい．

Mutexは単にひとつのスレッドからしか実行できないようにするもの．
Conditionは明示的に通知をしてスレッド間で同期を取ることができるもの．
Conditionの方がMutexよりも細かい制御ができる．

コードが間違っていたので訂正．
wait/notifyを呼ぶときにはロックを取得していなければならない．
これはどういうことかと言うと，Conditionに渡したMutex mをロックするためにsynchronized (m)ブロックを作って，その中でwait/notifyを呼ばなければならないということ．

また，notifyを呼び出しても，waitしているスレッドがすぐに m のロックを再取得して処理を継続するわけではない．
notifyを呼び出したときには「notify を呼び出したスレッド」がmをロックしているので，wait側は m をロックすることができないから．
notify側が m のロックを解放するタイミングをちゃんと用意してあげること．

import std.stdio;
import core.thread;
import core.sync.mutex;
import core.sync.condition;

// 別のスレッドでカウントを3回表示するまで待ってから終了する
void main()
{
	auto m = new Mutex; // 排他処理用のmutexを作って
	auto c = new Condition(m); // conditionに渡す
	void f()// スレッドのエントリポイント
	{
		foreach (i; 0..3)
		{
			writeln("\t", i); // カウントを3回表示して
		}
		synchronized (m) // cじゃなくてmのロックを取る
			c.notify(); // mに対するwaitを起こす
		writeln("\tend"); // このスレッドを終了
	}
	auto t = new Thread(&f); // スレッドを作成
	t.start(); // スレッド開始
	writeln("0");
	synchronized (m) // cじゃなくてmのロックを取る
		c.wait(); // mに対してnotifyが呼ばれるまで停止する
	writeln("END");
}

本来これだけの処理ならばメインスレッドで t.join() を呼び出してスレッドの終了を待てば十分だろう．

マルチスレッドを勉強しながらなのでこれからも間違える可能性が高いでしょう．